Cream of the Crop 26/Cream of the Crop 26.iso/doom/addons.zip/MOSH100.ZIP/MOSH.REF

Text File | 1997-07-30 | 10KB | 521 lines

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                                          ;;
;;          ::[[ BoneTown Moshpit IGM by Curious Yellow v1.00 ]]::          ;;
;;                                                                          ;;
;;                   http://home.earthlink.net/~csyellow                    ;;
;;                                                                          ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

@#PAY
; Reset all `p variables that are used for this IGM..
@do `p22 is 0
@do `p23 is 0
@do `p51 is 0
@do `p52 is 0
@do `p53 is 0
@do `p54 is 0
@do `p55 is 0
@do `p56 is 0
@do `p57 is 0
; makes player "off the map" until they return or enter the concert hall
@offmap
@datanewday MOSH.IDF
@dataload MOSH.IDF &playernum `p21
@if `p21 not 0 then do
  @begin
  @do moveback
  @do saybar
  `0The concert hall is empty. Better come back tomorrow.
  @closescript
  @end

@SHOW
`^`r0
`c  `r1`% Not So Fast.. `r0
`0
  "Hold it there.. you've gotta pay `$$100 `0to get in here."

  `%"Why would I want to, eh?"

  `0"Cuz `$RESIDUE`0 is playing. That should be reason enough."

@do `v01 is 2
@choice
>&money 99 Okay, I can spare the cash.
<&money 100 Hey.. those are nice shoes, dude!
Who the heck is RESIDUE?
Screw this, man!
@if responce is 1 then do
  @begin
  @do `p21 is 1
  @datasave MOSH.IDF &playernum `p21
  @show
`c  `%"Trust me.. you won't be disappointed."`\`k
  @loadmap 2
  @do map is 2
  @do x is 39
  @do y is 17
  @DRAWMAP
  @update
  @DO SAYBAR
  `%This is the biggest moshpit you have ever SEEN!
  @UPDATE
  @do money - 100
  @CLOSESCRIPT
  @end
@if responce is 2 then do
  @begin
  @do `p20 random 10 1
    @if `p20 is 8 then do
      @begin
      @do `p21 is 1
      @datasave MOSH.IDF &playernum `p21
      @show
`c  `%"You sound like a nice kid.. I'll let you in for free."`\`k
      @loadmap 2
      @do map is 2
      @do x is 39
      @do y is 17
      @DRAWMAP
      @update
      @DO SAYBAR
      `%This is the biggest moshpit you have ever SEEN!
      @UPDATE
      @CLOSESCRIPT
      @end
    @if `p20 not 8 then do
      @begin
      @show
`c`r0  `r1`% Nice Try. `r0

  `0Well, nice try, but the guard just got mad
  and beat the crap out of you.. *sigh*
`k
      @do `p02 is 5
      @do moveback
      @drawmap
      @update
      @do saybar
      `%"Punk! Get lost!"
      @closescript
      @end
  @end
@if responce is 3 then do
  @begin
  @show
`r0`c  `0"Only the coolest band in the world! Where have you been?!"

  `%"Avenging the death of my father."

  `0"Whatever, s&boy.."
`k
  @do goto PAY
  @end
@if responce is 4 then do
  @begin
  @do moveback
  @drawmap
  @update
  @do saybar
  `%"Well then.. Your loss, I guess."
  @closescript
  @end

@#TODD
@do saybar
`0Todd: `%"Paradiddle, paradiddle.. yeehaw!"
@closescript

@#SETH
@do saybar
`0Seth is flying through an extremely difficult riff..
@closescript

@#DAMON
@do saybar
`0Damon: `%"How the tom-henky did you get up here?!"
@closescript

@#JOE
@do saybar
`%"The Lester Colony rules! YEAH!" `0.. You wonder of Joe is 'all there'.
@closescript

@#DIVE
@if `p54 < 6 then do
  @begin
  @do move x y
  @show
 `W
  @do y + 1
  @update
  @do move x y
  @show
 `W
  @do y + 1
  @update
  @do move x y
  @show
 `W
  @do y + 1
  @update
  @do move x y
  @show
 `W
  @do y + 1
  @update
  @do `p54 + 1
  @do `p53 random 10 1
  @if `p53 < 6 then do
    @begin
    @do `p02 - 5
    @do saybar
    `0Oh, cripes! No one caught you! `$-5 HP!
    @if `p02 < 1 then do
      @begin
      @run DIE in GAMETXT.REF
      @closescript
      @end
    @closescript
    @end
  @if `p53 > 5 then do
    @begin
    @do `p55 random 20 5
    @do saybar
    `0Whoo! What a rush! `$+`p55 experience!
    @closescript
    @end
  @end
@do saybar
`0Your headache won't permit you to jump..
@closescript

@#ONSTAGE
@if &lasty not 4 then do
  @begin
  @do saybar
  `0Cool! You found a way to get on stage! ROCK ON!
  @closescript
  @end

@#BACKSTAGE
@if `p23 is 1 then do
  @begin
  @loadmap 3
  @do map is 3
  @do x is 40
  @do y is 10
  @do `p23 is 0
  @drawmap
  @update
  @closescript
  @end

@do saybar
`%Backstage? Haw!
@closescript

@#DRUMS
@do saybar
`$(it's SUPPOSED to be a drumset..)
@closescript

@#GUY
@if `p23 is 1 then do
  @begin
  @do saybar
  `0Shadowy Figure: `%"How 'bout that `$backstage pass`%! Cool, eh?"
  @closescript
  @end
@show
`c`r0  `r1`% Shady Figure `r0

  `0"I might be able to hook you up with a `$backstage pass`0.."

  `%"Oh? How much will it cost me, you bum?"

  `0"It WOULD HAVE cost you `$$1`0, but I'll make it
  `$$175`0 now for that 'bum' remark.. haw haw haw!"

@do `v01 is 2
@choice
>&money 174 Okay, I'll take it!
<&money 175 You wanker! I don't have the cash!
Bah. I don't trust you.
@if responce is 1 then do
  @begin
  @do money - 175
  @do `p23 is 1
  @show
`r0`c  `0"Trust me, my s&boy.. it's worth every penny."

  `2YOU NOW HAVE BACKSTAGE ACCESS!
`k
  @do moveback
  @drawmap
  @update
  @do saybar
  `%"You won't regret it!"
  @end
@if responce is 2 then do
  @begin
  @show
  `r0`c  `0"Then get out of my face, loser.."
`k
  @do moveback
  @drawmap
  @update
  @do saybar
  `0Geez. What a jerk.
  @closescript
  @end
@if responce is 3 then do
  @begin
  @do moveback
  @drawmap
  @update
  @do saybar
  `0"Fine then. Be that way."
  @closescript
  @end

@#EVENT
@do `p22 random 15 1
@if `p22 < 11 then do
  @begin
  @if y > 8 then do
    @begin
    @do goto pitfight
    @closescript
    @end
  @do goto stagefight
  @closescript
  @end
@if `p22 is 11 then do
  @begin
  @do saybar
  `%Dang! This band sounds AWESOME!
  @closescript
  @end
@if `p22 is 12 then do
  @begin
  @do saybar
  `%You slip in a puddle of vomit.
  @closescript
  @end
@if `p22 > 12 then do
  @begin
  @do saybar
  `%You found a nacho on the floor! YUM!
  @if `p02 < `p03 then do
    @begin
    @do `p02 + 1
    @end
  @closescript
  @end

@#PITFIGHT
@fight
;name
Mosher
;string said when you see him
`0The maniac is foaming at the mouth, smashing into everything around him..
;power move kill string
A smack to the face brings him to his senses.
;sex - 1 is male, 2 is female, 3 is it
1
;weapon and strength for the weapon, up to 5
elbows you|46
stomps on your feet|56
jumps at you headfirst|31
NONE|NONE
NONE|NONE
;defense
19
;gold reward
100
;experience
20
;hit points
80
;if win: ref file|name or NONE
NONE|NONE
;if lose: ref file|name or NONE
MOSH.REF|LOSE
;if runs: ref file|name or NONE
NONE|NONE
@end
@closescript

@#STAGEFIGHT
@fight
;name
Stage Diver
;string said when you see him
`0He looks ready to jump.. LOOK OUT!
;power move kill string
You step out of the way, and he falls flat on his face.
;sex - 1 is male, 2 is female, 3 is it
1
;weapon and strength for the weapon, up to 5
lands on you|46
flings himself at you|56
spits on you|31
NONE|NONE
NONE|NONE
;defense
25
;gold reward
121
;experience
25
;hit points
100
;if win: ref file|name or NONE
NONE|NONE
;if lose: ref file|name or NONE
MOSH.REF|LOSE
;if runs: ref file|name or NONE
NONE|NONE
@end
@closescript

@#LOSE
@do `p02 is 5
@loadmap 1287
@do map is 1287
@do x is 58
@do y is 5
@drawmap
@update
@do saybar
`0You're not dead, but you were thrown out for fighting..
@closescript

@#TV
@do saybar
`0An older model TV, but it works..
@closescript

@#BACKTODD
@do saybar
`0Todd: `%"Yo! Glad you could join the party!"
@closescript

@#BACKSETH
@do saybar
`0Seth: `%"Hey. Do you think we're any good?"
@closescript

@#BACKJOE
@if `p52 is 0 then do
  @begin
  @do saybar
  `0Joe: `%"GoatS&Boy .. Is that you?! Here! Take these `#gems`%!"
  @do `p19 + 10
  @do `p52 is 1
  @closescript
  @end
@do saybar
`0Joe: `%"You know, you look kinda familiar.."
@closescript

@#BACKDAMON
@do saybar
`0Damon is hitting on a groupie named `$"Penny"`0. Leave him alone.
@closescript

@#HOOKER
@if &sexmale not 0 then do
  @begin
  @do saybar
  `0Delilah: `%"Sorry, babe.. I ain't like that!"
  @closescript
  @end

@if `p56 is 1 then do
  @begin
  @do saybar
  `0Delilah: `%"You were amazing! Come back later, hon.."
  @closescript
  @end

@show
`c`r0  `r1 `%Delilah `r0

  `0"Hey, baby.. I'll give you a ride for `$$200`0, VD-Free!"

  `%You look the girl over, and decide she's pretty damn hot.

  `0"Well, handsome, what'll it be?"

@do `v01 is 2
@choice
>&money 199 Let me show you my bony maccaroni..
<&money 200 How 'bout a freebie?
No thanks, babe.. I'm pretty tired.
@if responce is 1 then do
  @begin
  @do money - 200
  @do goto NASTY
  @end
@if responce is 2 then do
  @begin
  @do `p57 random 10 1
  @if `p57 is 8 then do
    @begin
    @show
`\`0"Okay, baby.. but bring some green next time!"
@do goto NASTY
    @drawmap
    @update
    @closescript
    @end
  @end
@if responce is 3 then do
  @begin
  @do moveback
  @drawmap
  @update
  @do saybar
  `0"Oh.. shy, aren't you?"
  @closescript
  @end

@#NASTY
  @do `p56 is 1
  @do `p34 + 1
  @show
`c`r0  `r1 `%Doin' The Nasty `r0

  `%She leads you by the hand to a quiet backroom and slowly pulls off
  her clothes, and beckons for you to do the same. You undress, and
  join her on a plush, circular bed. You "protect" yourself, and start
  the action`L.`L.`L.`L.`L. *whew!* What a ride!

  `%You leave Delilah, asleep, and head back to the party.

`k
  @do moveback
  @drawmap
  @update
  @closescript

@#SEAT
@if `p51 is 0 then do
  @begin
  @do saybar
  `0You sit next to Todd and he hands you a soda. HP MAXED OUT!
  @do `p02 is `p03
  @do `p51 is 1
  @closescript
  @end
@do saybar
`0You kick back and relax next to Todd, 'n watch some TV..
@closescript

@#STEREO
@do saybar
`0Woman: `%"Isn't that the biggest stereo EVER?!"
@closescript